third persson prototype

godot/Scripts/Characters/Player.gd

@@ -0,0 +1,63 @@
+extends CharacterBody3D
+
+const LERP_VALUE : float = 0.15
+
+var snap_vector : Vector3 = Vector3.DOWN
+var speed : float
+
+@export_group("Movement variables")
+@export var walk_speed : float = 2.0
+@export var run_speed : float = 5.0
+@export var jump_strength : float = 15.0
+@export var gravity : float = 50.0
+
+const ANIMATION_BLEND : float = 7.0
+
+@onready var player_mesh : Node3D = $Mesh
+@onready var spring_arm_pivot : Node3D = $SpringArmPivot
+@onready var animator : AnimationTree = $AnimationTree
+
+func _physics_process(delta):
+	var move_direction : Vector3 = Vector3.ZERO
+	move_direction.x = Input.get_action_strength("move_right") - Input.get_action_strength("move_left")
+	move_direction.z = Input.get_action_strength("move_backwards") - Input.get_action_strength("move_forwards")
+	move_direction = move_direction.rotated(Vector3.UP, spring_arm_pivot.rotation.y)
+	
+	velocity.y -= gravity * delta
+	
+	if Input.is_action_pressed("run"):
+		speed = run_speed
+	else:
+		speed = walk_speed
+	
+	velocity.x = move_direction.x * speed
+	velocity.z = move_direction.z * speed
+	
+	if move_direction:
+		player_mesh.rotation.y = lerp_angle(player_mesh.rotation.y, atan2(velocity.x, velocity.z), LERP_VALUE)
+	
+	var just_landed := is_on_floor() and snap_vector == Vector3.ZERO
+	var is_jumping := is_on_floor() and Input.is_action_just_pressed("jump")
+	if is_jumping:
+		velocity.y = jump_strength
+		snap_vector = Vector3.ZERO
+	elif just_landed:
+		snap_vector = Vector3.DOWN
+	
+	apply_floor_snap()
+	move_and_slide()
+	animate(delta)
+
+func animate(delta):
+	if is_on_floor():
+		animator.set("parameters/ground_air_transition/transition_request", "grounded")
+		
+		if velocity.length() > 0:
+			if speed == run_speed:
+				animator.set("parameters/iwr_blend/blend_amount", lerp(animator.get("parameters/iwr_blend/blend_amount"), 1.0, delta * ANIMATION_BLEND))
+			else:
+				animator.set("parameters/iwr_blend/blend_amount", lerp(animator.get("parameters/iwr_blend/blend_amount"), 0.0, delta * ANIMATION_BLEND))
+		else:
+			animator.set("parameters/iwr_blend/blend_amount", lerp(animator.get("parameters/iwr_blend/blend_amount"), -1.0, delta * ANIMATION_BLEND))
+	else:
+		animator.set("parameters/ground_air_transition/transition_request", "air")

godot/Scripts/Characters/SpringArmPivot.gd

@@ -0,0 +1,30 @@
+extends Node3D
+
+@export_group("FOV")
+@export var change_fov_on_run : bool
+@export var normal_fov : float = 75.0
+@export var run_fov : float = 90.0
+
+const CAMERA_BLEND : float = 0.05
+
+@onready var spring_arm : SpringArm3D = $SpringArm3D
+@onready var camera : Camera3D = $SpringArm3D/Camera3D
+
+func _ready():
+	Input.set_mouse_mode(Input.MOUSE_MODE_CAPTURED)
+
+func _unhandled_input(event):
+	if event is InputEventMouseMotion:
+		rotate_y(-event.relative.x * 0.005)
+		spring_arm.rotate_x(-event.relative.y * 0.005)
+		spring_arm.rotation.x = clamp(spring_arm.rotation.x, -PI/4, PI/4)
+
+func _physics_process(_delta):
+	if change_fov_on_run:
+		if owner.is_on_floor():
+			if Input.is_action_pressed("run"):
+				camera.fov = lerp(camera.fov, run_fov, CAMERA_BLEND)
+			else:
+				camera.fov = lerp(camera.fov, normal_fov, CAMERA_BLEND)
+		else:
+			camera.fov = lerp(camera.fov, normal_fov, CAMERA_BLEND)